Bonjour,

Dans de deux nombreux ouvrages de descendance complète, le nom des
parents des conjoints est donné. Le programme suivant permet de
retrouver tous les conjoints qui n'ont pas de parents dans la base.

Les sélections sont la personne de base et une année maximum de mariage.
Il n'est pas utile d'éditer les mariages qui ont eu lieu après la
parution.

=========== conjpar.ll ==========
char_encoding("UTF-8")

proc main()
{
    set(sep, ";")
    set(cpt1, 0)
    set(cpt2, 0)
    set(cpt3, 0)
    getindi(base, "Descendance à prendre en compte")
    getint(annee, "Année maximum")
    "nom;prénoms;clé;naiss;mar;décès\n"
    indiset(setbase)
    addtoset(setbase, base, 0)
    indiset(setdesc)
    set(setdesc, descendentset(setbase))
    set(cpt1, length(setdesc))
    forindiset(setdesc, oneindi, bidon, cpt) {
        spouses(oneindi, onespouse, fami, cpts) {
            if(not(parents(onespouse))) {
                incr(cpt2)
                if(year(marriage(fami))) {
                    set(mardate, strtoint(year(marriage(fami))))
                }
                else {
                    /* mettre 9999 si on ne veut pas
                       les mariages sans date */
                    set(mardate, 0)
                }
                if(le(mardate, annee)) {
                    incr(cpt3)
                    surname(onespouse) sep
                    givens(onespouse) sep
                    key(onespouse) sep
                    date(birth(onespouse)) sep
                    date(marriage(fami)) sep
                    date(death(onespouse))
                    "\n"
                }
            }
        }
    }
    print(d(cpt1), " descendants :\n")
    print(d(cpt2), " couples de beaux-parents manquants : ")
    set(bidon, sub(cpt2, cpt3))
    print(d(cpt3), " écrits, ", d(bidon), " trop récents")
}
===========================================================
--
 Patrick Texier

 vim:syntax=mail:ai:ts=4:et:tw=72